Difference between revisions of "Sed/scripts"

From Christoph's Personal Wiki
Jump to: navigation, search
 
(→‎Miscellaneous)
 
(39 intermediate revisions by the same user not shown)
Line 27: Line 27:
  
 
* number each line of a file (simple left alignment). Using a tab (see note on '\t' at end of file) instead of space will preserve margins.
 
* number each line of a file (simple left alignment). Using a tab (see note on '\t' at end of file) instead of space will preserve margins.
−
  sed = filename | sed 'N;s/\n/\t/'
+
  sed = filename | sed 'N;{{Regex/Replace|\n|\t||}}'
  
 
* number each line of a file (number on left, right-aligned)
 
* number each line of a file (number on left, right-aligned)
−
  sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'
+
  sed = filename | sed 'N; {{Regex/Replace|^|     ||}}; {{Regex/Replace| *\(.\{6,\}\)\n|\1  ||}}'
  
 
* number each line of file, but only print numbers if line is not blank
 
* number each line of file, but only print numbers if line is not blank
−
  sed '/./=' filename | sed '/./N; s/\n/ /'
+
  sed '/./=' filename | sed '/./N; {{Regex/Replace|\n| ||}}'
  
−
* count lines (emulates "wc -l")
+
* count lines (emulates "<code>wc -l</code>")
 
  sed -n '$='
 
  sed -n '$='
  
Line 41: Line 41:
  
 
* IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format.
 
* IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format.
−
  sed 's/.$//'          # assumes that all lines end with CR/LF
+
  sed '{{Regex/Replace|.$|||}}'          # assumes that all lines end with CR/LF
−
  sed 's/^M$//'          # in bash/tcsh, press Ctrl-V then Ctrl-M
+
  sed '{{Regex/Replace|^M$|||}}'          # in bash/tcsh, press Ctrl-V then Ctrl-M
 
  sed 's/\x0D$//'        # works on ssed, gsed 3.02.80 or higher
 
  sed 's/\x0D$//'        # works on ssed, gsed 3.02.80 or higher
  
Line 60: Line 60:
  
 
* delete leading whitespace (spaces, tabs) from front of each line aligns all text flush left
 
* delete leading whitespace (spaces, tabs) from front of each line aligns all text flush left
−
  sed 's/^[ \t]*//'      # see note on '\t' at end of file
+
  sed '{{Regex/Replace|^[ \t]*|||}}'      # see note on '\t' at end of file
  
 
* delete trailing whitespace (spaces, tabs) from end of each line
 
* delete trailing whitespace (spaces, tabs) from end of each line
−
  sed 's/[ \t]*$//'      # see note on '\t' at end of file
+
  sed '{{Regex/Replace|[ \t]*$|||}}'      # see note on '\t' at end of file
  
 
* delete BOTH leading and trailing whitespace from each line
 
* delete BOTH leading and trailing whitespace from each line
−
  sed 's/^[ \t]*//;s/[ \t]*$//'
+
  sed '{{Regex/Replace|^[ \t]*|||}};{{Regex/Replace|[ \t]*$|||}}'
  
 
* insert 5 blank spaces at beginning of each line (make page offset)
 
* insert 5 blank spaces at beginning of each line (make page offset)
−
  sed 's/^/     /'
+
  sed '{{Regex/Replace|^|     ||}}'
 +
 
 +
* break up a stream of characters into 60 per line (i.e. 60-column width)<ref name=champ>Christoph Champ's additions</ref>
 +
sed -e '{{Regex/Replace|\(.\{60\}\)|\1\n|g}}'
  
 
* align all text flush right on a 79-column width
 
* align all text flush right on a 79-column width
−
  sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # set at 78 plus 1 space
+
  sed -e :a -e '{{Regex/Replace|^.\{1,78\}$| &|;ta}}'  # set at 78 plus 1 space
  
 
* center all text in the middle of 79-column width. In method 1, spaces at the beginning of the line are significant, and trailing spaces are appended at the end of the line. In method 2, spaces at the beginning of the line are discarded in centering the line, and no trailing spaces appear at the end of lines.
 
* center all text in the middle of 79-column width. In method 1, spaces at the beginning of the line are significant, and trailing spaces are appended at the end of the line. In method 2, spaces at the beginning of the line are discarded in centering the line, and no trailing spaces appear at the end of lines.
−
  sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                    # method 1
+
  sed  -e :a -e '{{Regex/Replace|^.\{1,77\}$| & |;ta}}'                    # method 1
−
  sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # method 2
+
  sed  -e :a -e '{{Regex/Replace|^.\{1,77\}$| &|;ta}}' -e '{{Regex/Replace|\( *\)\1|\1||}}'  # method 2
  
 
* substitute (find and replace) "foo" with "bar" on each line
 
* substitute (find and replace) "foo" with "bar" on each line
−
  sed 's/foo/bar/'            # replaces only 1st instance in a line
+
  sed '{{Regex/Replace|foo|bar|}}'            # replaces only 1st instance in a line
−
  sed 's/foo/bar/4'            # replaces only 4th instance in a line
+
  sed '{{Regex/Replace|foo|bar|4}}'            # replaces only 4th instance in a line
−
  sed 's/foo/bar/g'            # replaces ALL instances in a line
+
  sed '{{Regex/Replace|foo|bar|g}}'            # replaces ALL instances in a line
−
  sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # replace the next-to-last case
+
  sed '{{Regex/Replace|\(.*\)foo\(.*foo\)|\1bar\2|}}' # replace the next-to-last case
−
  sed 's/\(.*\)foo/\1bar/'            # replace only the last case
+
  sed '{{Regex/Replace|\(.*\)foo|\1bar|}}'            # replace only the last case
  
 
* substitute "foo" with "bar" ONLY for lines which contain "baz"
 
* substitute "foo" with "bar" ONLY for lines which contain "baz"
−
  sed '/baz/s/foo/bar/g'
+
  sed '/baz/{{Regex/Replace|foo|bar|g}}'
  
 
* substitute "foo" with "bar" EXCEPT for lines which contain "baz"
 
* substitute "foo" with "bar" EXCEPT for lines which contain "baz"
−
  sed '/baz/!s/foo/bar/g'
+
  sed '/baz/!{{Regex/Replace|foo|bar|g}}'
  
 
* change ("scarlet" or "ruby" or "puce") to ("red")
 
* change ("scarlet" or "ruby" or "puce") to ("red")
−
  sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'  # most seds
+
  sed '{{Regex/Replace|scarlet|red|g}};{{Regex/Replace|ruby|red|g}};{{Regex/Replace|puce|red|g}}'  # most seds
−
gsed 's/scarlet\|ruby\|puce/red/g'                # GNU sed only
+
  
−
* reverse order of lines (emulates "tac") bug/feature in HHsed v1.5 causes blank lines to be deleted
+
gsed '{{Regex/Replace|scarlet\<nowiki>|</nowiki>ruby\<nowiki>|</nowiki>puce|red|g}}'                # GNU sed only
 +
 
 +
* reverse order of lines (emulates "[[Tac (command)|tac]]") bug/feature in HHsed v1.5 causes blank lines to be deleted
 
  sed '1!G;h;$!d'              # method 1
 
  sed '1!G;h;$!d'              # method 1
 
  sed -n '1!G;h;$p'            # method 2
 
  sed -n '1!G;h;$p'            # method 2
  
−
* reverse each character on the line (emulates "rev")
+
* reverse each character on the line (emulates "[[Rev (command)|rev]]")
−
  sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
+
  sed '/\n/!G;{{Regex/Replace|\(.\)\(.*\n\)|&\2\1||}};//D;{{Regex/Replace|.|||}}'
 +
 
 +
* join pairs of lines side-by-side (like "[[Paste (command)|paste]]")
 +
sed '$!N;{{Regex/Replace|\n| ||}}'
  
−
* join pairs of lines side-by-side (like "paste")
+
* delete all newlines (i.e. append next line loop)<ref name=champ>Christoph Champ's additions</ref>
−
  sed '$!N;s/\n/ /'
+
  sed -e :a -e '$!N;{{Regex/Replace|\n||;ta}}'    # method 1
 +
sed -e :a -e '$b;N;{{Regex/Replace|\n||;ba}}'   # method 2
  
 
* if a line ends with a backslash, append the next line to it
 
* if a line ends with a backslash, append the next line to it
−
  sed -e :a -e '/\\$/N; s/\\\n//; ta'
+
  sed -e :a -e '/\\$/N; {{Regex/Replace|\\\n||; ta}}'
  
 
* if a line begins with an equal sign, append it to the previous line and replace the "=" with a single space
 
* if a line begins with an equal sign, append it to the previous line and replace the "=" with a single space
−
  sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'
+
  sed -e :a -e '$!N;{{Regex/Replace|\n<nowiki>=</nowiki>| |;ta}}' -e 'P;D'
  
 
* add commas to numeric strings, changing "1234567" to "1,234,567"
 
* add commas to numeric strings, changing "1234567" to "1,234,567"
−
  gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                    # GNU sed
+
  gsed ':a;{{Regex/Replace|\B[0-9]\{3\}\>|,&|;ta}}'                    # GNU sed
−
  sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # other seds
+
  sed -e :a -e '{{Regex/Replace|\(.*[0-9]\)\([0-9]\{3\}\)|\1,\2|;ta}}'  # other seds
  
 
* add commas to numbers with decimal points and minus signs (GNU sed)
 
* add commas to numbers with decimal points and minus signs (GNU sed)
−
  gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'
+
  gsed -r ':a;{{Regex/Replace|(^<nowiki>|</nowiki>[^0-9.])([0-9]+)([0-9]{3})|\1\2,\3|g;ta}}'
  
 
* add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
 
* add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
Line 124: Line 132:
 
== Selective printing of certain lines ==
 
== Selective printing of certain lines ==
  
−
* print first 10 lines of file (emulates behavior of "head")
+
* print first 10 lines of file (emulates behaviour of "head")
 
  sed 10q
 
  sed 10q
  
Line 207: Line 215:
 
* print section of file between two regular expressions (inclusive)
 
* print section of file between two regular expressions (inclusive)
 
  sed -n '/Iowa/,/Montana/p'            # case sensitive
 
  sed -n '/Iowa/,/Montana/p'            # case sensitive
 +
 +
* print only the last line that matches REGEX pattern:
 +
sed -ne '/REGEX/h;${x;p}'
  
 
== Selective deletion of certain lines ==
 
== Selective deletion of certain lines ==
Line 212: Line 223:
 
* print all of file EXCEPT section between 2 regular expressions
 
* print all of file EXCEPT section between 2 regular expressions
 
  sed '/Iowa/,/Montana/d'
 
  sed '/Iowa/,/Montana/d'
 +
 +
* delete every paragraph containing "FOO"<ref name=champ>Christoph Champ's additions</ref>
 +
sed -e '/^$/b; :loop; $!{ N; /\n$/!b loop; }; /FOO/d'
  
 
* delete duplicate, consecutive lines from a file (emulates "uniq"). First line in a set of duplicate lines is kept, rest are deleted.
 
* delete duplicate, consecutive lines from a file (emulates "uniq"). First line in a set of duplicate lines is kept, rest are deleted.
Line 262: Line 276:
 
* delete the last line of each paragraph
 
* delete the last line of each paragraph
 
  sed -n '/^$/{p;h;};/./{x;/./p;}'
 
  sed -n '/^$/{p;h;};/./{x;/./p;}'
 +
 +
* delete (strip) all HTML tags (not the line, just the tag; e.g. <nowiki><p></p></nowiki>):<ref name=champ>Christoph Champ's additions</ref>
 +
sed -e 's#<[^>]*>##g'
 +
#~OR~
 +
sed -e '{{Regex/Replace|<[^>]*>||g}}'
 +
#~OR~
 +
sed 's/<[^>]\+>//g'
 +
 +
 +
* delete (strip) all text within brackets/parentheses, including the brackets/parentheses:
 +
$ echo "foo [bar] baz" | sed -e 's/\[[^][]*\]//g' # => "foo  baz"
 +
$ echo "foo (bar) baz" | sed -e 's/([^()]*)//g'  # => "foo  baz"
 +
 +
== Date formats ==
 +
* Convert from "<code>10/20/1998</code>" to "<code>1998-10-20</code>"<ref name=champ>Christoph Champ's additions</ref>
 +
$ sed -n -e "s_\(..\)/\(..\)/\(....\)_\3-\1-\2_p"
 +
$ #~OR~
 +
$ echo 10/20/1998 |sed -E 's,([0-9]{2})/([0-9]{2})/([0-9]{4}),\3-\2-\1,g'
 +
 +
Note: You can also accomplish the above with:
 +
$ date --date='10/20/1998' '+%F'
  
 
== Special applications ==
 
== Special applications ==
Line 305: Line 340:
 
  echo @echo off >zipup.bat
 
  echo @echo off >zipup.bat
 
  dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat
 
  dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat
 +
 +
==Miscellaneous==
 +
 +
* Replace string1 with string2<ref name=champ>Christoph Champ's additions</ref>
 +
sed '{{Regex/Replace|string1|string2|g}}'
 +
* Modify anystring1 to anystring2<ref name=champ>Christoph Champ's additions</ref>
 +
sed '{{Regex/Replace|\(.*\)1|\12|g}}'
 +
* Remove comments and blank lines<ref name=champ>Christoph Champ's additions</ref>
 +
sed '/ *#/d; /^ *$/d'
 +
* Concatenate lines with trailing \<ref name=champ>Christoph Champ's additions</ref>
 +
sed ':a; /\\$/N; {{Regex/Replace|\\\n||; ta}}'
 +
* Remove trailing spaces from lines<ref name=champ>Christoph Champ's additions</ref>
 +
sed '{{Regex/Replace|[ \t]*$||}}'
 +
* Escape shell metacharacters active within double quotes<ref name=champ>Christoph Champ's additions</ref>
 +
sed '{{Regex/Replace|\([\\`\\"$\\\\]\)|\\\1|g}}'
 +
* Print 1000th line<ref name=champ>Christoph Champ's additions</ref>
 +
sed -n '1000p;1000q'
 +
* Print lines 10 to 20<ref name=champ>Christoph Champ's additions</ref>
 +
sed -n '10,20p;20q'
 +
* Extract title from HTML web page<ref name=champ>Christoph Champ's additions</ref>
 +
sed -n '{{Regex/Replace|.*<[tT][iI][tT][lL][eE]>\(.*\)<\/[tT][iI][tT][lL][eE]>.*|\1|p;T;q}}'
 +
* Sort IPV4 ip addresses<ref name=champ>Christoph Champ's additions</ref>
 +
sort -t. -k1,1n -k2,2n -k3,3n -k4,4n
 +
* Insert text at a given line (e.g., insert "foo" into a file at line 5):
 +
sed -i '5i foo' file.txt
 +
* Case conversion<ref name=champ>Christoph Champ's additions</ref>
 +
echo 'Test' | tr '[:lower:]' '[:upper:]'
 +
* Filter non printable characters<ref name=champ>Christoph Champ's additions</ref>
 +
tr -dc '[:print:]' < /dev/urandom
 +
* Count lines<ref name=champ>Christoph Champ's additions</ref>
 +
grep 'processor' /proc/cpuinfo | wc -l
 +
 +
* In line 2, looks for the string '<code>limits.*</code>' where * is any string, and replaces with '<code>hello</code>'<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
sed '2 {{Regex/Replace|limits.*|hello||}}'
 +
 +
* Substitutes '<code>try</code>' for the first occurence of '<code>junk</code>' in lines 2 through 4 only<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
sed '2,4 {{Regex/Replace|junk|try||}}
 +
 +
* Appends the string '<code>set c=818.</code>' after line 8<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
sed '8 a\set c=818.'
 +
 +
* Appends the string '<code>set i1=(i+c)/c - 1</code>' after line 8. Note the use of the \ is needed to print out 'special characters', like /, &, %, $, and of course, \ itself<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
sed '8 a\set i1=(i+c)\/c - 1'
 +
 +
* Inserts the string '<code>set c=818.</code>' before line 8<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
sed '8 i\set c=818.'
 +
 +
* Piping streams through sed<ref name=Hartigan>Patrick Hartigan's additions</ref>
 +
ls file* | sed 's/.*/cat & | sed -f a.sed > tmp; mv -f tmp &/' > doit
 +
 +
*Append lines ''n'',''m'' in a loop<ref name=champ>Christoph Champ's additions</ref>
 +
Say you have a file, <code>foo</code>, that has the following 10 lines:
 +
A1
 +
A2
 +
A3
 +
A4
 +
A5
 +
B1
 +
B2
 +
B3
 +
B4
 +
B5
 +
and you want to convert it to look like the following:
 +
A1A2A3A4A5
 +
B1B2B3B4B5
 +
Then, issue this command:
 +
for i in $(seq 1 5 10);\
 +
  do sed -n $(echo "$i,$(echo -e "$i+4"|bc -q)")'p' foo |\
 +
      sed -e :a -e '$b;N;s/\n//;ba';\
 +
done
 +
Note: There are easier ways to accomplish this; I am just showing a cool way to do it with sed.
 +
 +
*Convert from rows to numbered columns<ref name=champ>Christoph Champ's additions</ref>
 +
Say you have a file, <code>foo</code>, that has the following (single) line:
 +
FOO1  FOO2 BAR1 BAR2
 +
where the spaces can be any length and/or tabs.
 +
 +
If you wish the output to look like the following:
 +
1    FOO1
 +
2    FOO2
 +
3    BAR1
 +
4    BAR2
 +
Then, issue this command:
 +
sed -e '{{Regex/Replace|[ \t]|\n|g}}' -e '/^$/d'|sed =|sed 'N;{{Regex/Replace|\n|\t||}}'
 +
(.*): (.*)/
 +
*Convert named telephone numbers:
 +
sed 's/[abc]/2/gi;s/[def]/3/gi;s/[ghi]/4/gi;s/[jkl]/5/gi;s/[mno]/6/gi;s/[pqrs]/7/gi;s/[tuv]/8/gi;s/[wxyz]/9/gi' <<<"1-800-SHOWNUM"
 +
 +
*Increment the first digit in a number in a string with single quotes:
 +
# '101': 'foo' -> '201': 'foo'
 +
echo "'101': 'foo'"|sed -r -e "{{Regex/Replace|'||g}}" -e '{{Regex/Replace|([0-9])(.*): (.*)|echo $((\1+1))\2: \3|e}}' -e "{{Regex/Replace|(.*): (.*)|\\'\1\\': \\'\2\\'|}}"
 +
 +
*Pipe redirection:
 +
$ echo "foo" | sed -e '{{Regex/Replace|o|X|g}}' <&0
 +
fXX
 +
 +
*Directory nested tree:
 +
$ find . -type d | sed 's:[^-][^/]*/:--:g; s:^-: |:'
 +
 +
* Rename similar files such that the "date" part of the filename will change to be one day behind the original ''without'' overwriting the contents of the files:
 +
# E.g., Rename:      FROM -> TO
 +
# results-2014-10-09.json -> results-2014-10-08.json
 +
# results-2014-10-10.json -> results-2014-10-09.json
 +
# results-2014-10-11.json -> results-2014-10-10.json
 +
for f in *.json; do\
 +
  mv "$f" "$(echo $f|sed -e 's|\(results-\)\(.*\).json|echo $(date -d "\2-1day" +"%F")XXX\1|e' -e 's/\(.*\)XXX\(.*\)/\2\1.json/')"
 +
done
 +
 +
One could accomplish a similar way of renaming files using pure [[Bash]]:
 +
# Rename:
 +
# FROM: "Introduction___Networking_tutorial_(1_of_13)-qHzZUmP1vvON.mp4"
 +
#  TO: "nettut-01_of_13_-_Introduction-qHzZUmP1vvON.mp4"
 +
for f in *.mp4; do \
 +
  [[ $f =~ ^(.*)___Networking_tutorial_\(([0-9]+)_of_13\)-(.*)$ ]]
 +
  mv "$f" "nettut-$(printf "%02d" ${BASH_REMATCH[2]})_of_13_-_${BASH_REMATCH[1]}-${BASH_REMATCH[3]}"
 +
done
 +
There are obviously much easier ways to do the above. This is just an example to show the power of Bash.
 +
 +
* Parse output of ping for packet loss value:
 +
$ ping -c 5 -W 0.2 -q www.google.com | sed -rn "/packet loss/ s|.*([0-9]+)%.*|\1|p"
 +
 +
* Increment number in a given line matching the regex:
 +
$ sed -i -r 's/^(security.provider.)([0-9]+)=(.*)/echo "\1\$((\2+1))=\3"/ge' java.security
 +
 +
* Convert date formats:
 +
<pre>
 +
$ cat transactions.csv
 +
"Date","Activity Type","Amount"
 +
"07/22/19","bob","$23.51"
 +
"07/18/19","alice","$67.92"
 +
"06/21/19","bob","$12.42"
 +
 +
$ sed -n '/alice/p' transactions.csv |\
 +
  sed -e 's/"\(.*\)",".*","\$\(.*\)"/echo $(date -d "\1" "+%Y-%m-%d") \2/e'
 +
2019-07-18 67.92
 +
</pre>
 +
 +
* Verify that a TLS certificate stored in a kubeconfig file has not expired:
 +
<pre>
 +
$ cat ~/.kube/config
 +
apiVersion: v1
 +
kind: Config
 +
clusters:
 +
- name: "local"
 +
  cluster:
 +
    server: "https://rancher.example.com/k8s/clusters/local"
 +
    certificate-authority-data: "LS0tLS1CRUdJTiBDRVJUSUZJQ0FURS0tLS0tCk1JSUdIRENDQ\
 +
      kFTZ0F3SUJBZ0lKQU1vbTB2ZG5iTU9mTUEwR0NTcUdTSWIzRFFFQkN3VUFNSUdhTVFzd0NRWUQKV\
 +
      lFRR0V3SlZVekVUTUJFR0ExVUVDQXdLVjJGemFHbHVaM1J2YmpFUU1BNEdBMVVFQnd3SFUyVmhkS\
 +
      k3MVd0V3Brc3lpK1NJNWxpMGtLZCs4UDdKR0JkcGdZSkhWOWZib3E0WjBRWnNSeFRVClVnYeasdf"
 +
...
 +
users:
 +
- name: "user-nff34"
 +
...
 +
 +
$ sed -n '/certificate-authority-data/,/"/p' ~/.kube/config |\
 +
  sed -e 's/certificate-authority-data://' -e :a -e '/\\$/N; s/\\\n//; s/ //g; s/"//g; ta' |\
 +
  base64 -d | openssl x509 -enddate -noout -in -
 +
notAfter=Aug  4 23:38:12 2038 GMT
 +
</pre>
  
 
== Comments ==
 
== Comments ==
Line 338: Line 533:
 
=== Optimizing for speed ===
 
=== Optimizing for speed ===
 
If execution speed needs to be increased (due to large input files or slow processors or hard disks), substitution will be executed more quickly if the "find" expression is specified before giving the "s/.../.../" instruction. Thus:
 
If execution speed needs to be increased (due to large input files or slow processors or hard disks), substitution will be executed more quickly if the "find" expression is specified before giving the "s/.../.../" instruction. Thus:
−
 
+
−
  sed 's/foo/bar/g' filename        # standard replace command
+
sed 's/foo/bar/g' filename        # standard replace command
−
  sed '/foo/ s/foo/bar/g' filename  # executes more quickly
+
sed '/foo/ s/foo/bar/g' filename  # executes more quickly
−
  sed '/foo/ s//bar/g' filename      # shorthand sed syntax
+
sed '/foo/ s//bar/g' filename      # shorthand sed syntax
  
 
On line selection or deletion in which you only need to output lines from the first part of the file, a "quit" command (q) in the script will drastically reduce processing time for large files. Thus:
 
On line selection or deletion in which you only need to output lines from the first part of the file, a "quit" command (q) in the script will drastically reduce processing time for large files. Thus:
  
−
  sed -n '45,50p' filename          # print line nos. 45-50 of a file
+
sed -n '45,50p' filename          # print line nos. 45-50 of a file
−
  sed -n '51q;45,50p' filename      # same, but executes much faster
+
sed -n '51q;45,50p' filename      # same, but executes much faster
 +
 
 +
== POSIX character classes==
 +
''Note: See <code>`man 1 tr`</code>.''
 +
{| align="center" style="border: 1px solid #999; background-color:#FFFFFF"
 +
|-
 +
|-align="center" bgcolor="#1188ee"
 +
!POSIX
 +
!Description
 +
!ASCII
 +
!Unicode
 +
!Shorthand
 +
|-
 +
|<code>[:alnum:]</code> || Alphanumeric characters || <code>[a-zA-Z0-9]</code> || <code>[\p{L&}\p{Nd}]</code> ||
 +
|-
 +
|<code>[:alpha:]</code> || Alphabetic characters || <code>[a-zA-Z]</code> || <code>\p{L&}</code> ||
 +
|-
 +
|<code>[:ascii:]</code> || ASCII characters || <code>[\x00-\x7F]</code> || <code>\p{InBasicLatin}</code> ||
 +
|-
 +
|<code>[:blank:]</code> || Space and tab || <code>[ \t]</code> || <code>[\p{Zs}\t]</code> || <code>\h</code>
 +
|-
 +
|<code>[:cntrl:]</code> || Control characters || <code>[\x00-\x1F\x7F]</code> || <code>\p{Cc}</code> ||
 +
|-
 +
|<code>[:digit:]</code> || Digits || <code>[0-9]</code> || <code>\p{Nd}</code> || <code>\d</code>
 +
|-
 +
|<code>[:graph:]</code> || Visible characters (i.e. anything except spaces, control characters, etc.) || <code>[\x21-\x7E]</code> || <code>[^\p{Z}\p{C}]</code> ||
 +
|-
 +
|<code>[:lower:]</code> || Lowercase letters || <code>[a-z]</code> || <code>\p{Ll}</code> ||
 +
|-
 +
|<code>[:print:]</code> || Visible characters and spaces (i.e. anything except control characters, etc.) || <code>[\x20-\x7E]</code> || <code>\P{C}</code> ||
 +
|-
 +
|<code>[:punct:]</code> || Punctuation and symbols || <code><nowiki>[!"#$%&'()*+,\-./:;<=>?@[\\\]^_`{|}~]</nowiki></code> || <code>[\p{P}\p{S}]</code> ||
 +
|-
 +
|<code>[:space:]</code> || All whitespace characters, including line breaks || <code>[ \t\r\n\v\f]</code> || <code>[\p{Z}\t\r\n\v\f]</code> || <code>\s</code>
 +
|-
 +
|<code>[:upper:]</code> || Uppercase letters || <code>[A-Z]</code> || <code>\p{Lu}</code> ||
 +
|-
 +
|<code>[:word:]</code> || Word characters (letters, numbers, and underscores) || <code>[A-Za-z0-9_]</code> || <code>[\p{L}\p{N}\p{Pc}]</code> || <code>\w</code>
 +
|-
 +
|<code>[:xdigit:]</code> || Hexadecimal digits || <code>[A-Fa-f0-9]</code> || <code>[A-Fa-f0-9]</code> ||
 +
|}
 +
 
 +
Note that not all of the above character classes are understood by earlier versions of <code>`sed`</code> and/or even by the latest versions.
 +
 
 +
$ <nowiki>echo "10,20,30"|sed -r 's/[[:digit:]]+,([[:digit:]]+),[[:digit:]]+/\1/' # => 20</nowiki>
 +
 +
$ <nowiki>echo "10,foo,(2007),bar" | sed -r 's/^[[:digit:]]+,.*,\(([[:digit:]]+)\),.*/\1/' # => 2007</nowiki>
  
 
== Credits ==
 
== Credits ==
Line 360: Line 601:
 
* S.G. Ravenhall &mdash; great de-html script
 
* S.G. Ravenhall &mdash; great de-html script
 
* Greg Ubben &mdash; many contributions & much help
 
* Greg Ubben &mdash; many contributions & much help
−
 
+
<references/>
 
== Further reading ==
 
== Further reading ==
 
* ''Sed & Awk, 2nd ed.''; by Dougherty, Dale and Robbins, Arnold; from Oreilly & Associates, ISBN 1-56592-225-5
 
* ''Sed & Awk, 2nd ed.''; by Dougherty, Dale and Robbins, Arnold; from Oreilly & Associates, ISBN 1-56592-225-5
Line 366: Line 607:
 
* ''Unix Awk and Sed Programmer's Interactive Workbook''; by Patsis, Peter; from Prentice Hall Computer Books, ISBN 0130826758
 
* ''Unix Awk and Sed Programmer's Interactive Workbook''; by Patsis, Peter; from Prentice Hall Computer Books, ISBN 0130826758
 
* ''Mastering Regular Expressions, 2nd ed.''; by Jeffrey E. F. Friedl; from O'Reilly & Associates, ISBN 0-596-00289-0
 
* ''Mastering Regular Expressions, 2nd ed.''; by Jeffrey E. F. Friedl; from O'Reilly & Associates, ISBN 0-596-00289-0
 +
 +
==See also==
 +
*[[Regular expression]]s
 +
*[[AWK programming language|awk]]
  
 
== External links ==
 
== External links ==
 
* http://sed.sourceforge.net/sed1line.txt
 
* http://sed.sourceforge.net/sed1line.txt
 
* http://www.pement.org/sed/sed1line.txt
 
* http://www.pement.org/sed/sed1line.txt
 +
* [http://sed.sourceforge.net/grabbag/ Seder's grab bag]
 +
* [http://www.student.northpark.edu/pemente/sed/index.htm Eric Pement's sed page]
 +
* [http://www.rtfiber.com.tw/~changyj/sed Yao-Jen Chang's sed page]
  
 
[[Category:Linux Command Line Tools]]
 
[[Category:Linux Command Line Tools]]
 
[[Category:Scripting languages]]
 
[[Category:Scripting languages]]

Latest revision as of 22:47, 21 August 2019

The following is a compilation of useful one-line scripts for sed. The original was compiled by Eric Pement (29-Dec-2005; v5.5), however, I have converted it into the wiki format and have added more examples (always adding more).

File spacing

  • double space a file
sed G
  • double space a file which already has blank lines in it. Output file should contain no more than one blank line between lines of text.
sed '/^$/d;G'
  • triple space a file
sed 'G;G'
  • undo double-spacing (assumes even-numbered lines are always blank)
sed 'n;d'
  • insert a blank line above every line which matches "regex"
sed '/regex/{x;p;x;}'
  • insert a blank line below every line which matches "regex"
sed '/regex/G'
  • insert a blank line above and below every line which matches "regex"
sed '/regex/{x;p;x;G;}'

Numbering

  • number each line of a file (simple left alignment). Using a tab (see note on '\t' at end of file) instead of space will preserve margins.
sed = filename | sed 'N;s/\n/\t/'
  • number each line of a file (number on left, right-aligned)
sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'
  • number each line of file, but only print numbers if line is not blank
sed '/./=' filename | sed '/./N; s/\n/ /'
  • count lines (emulates "wc -l")
sed -n '$='

Text conversion and substitution

  • IN UNIX ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format.
sed 's/.$//'           # assumes that all lines end with CR/LF
sed 's/^M$//'          # in bash/tcsh, press Ctrl-V then Ctrl-M
sed 's/\x0D$//'        # works on ssed, gsed 3.02.80 or higher
  • IN UNIX ENVIRONMENT: convert Unix newlines (LF) to DOS format.
sed "s/$/`echo -e \\\r`/"      # command line under ksh
sed 's/$'"/`echo \\\r`/"       # command line under bash
sed "s/$/`echo \\\r`/"         # command line under zsh
sed 's/$/\r/'                  # gsed 3.02.80 or higher
  • IN DOS ENVIRONMENT: convert Unix newlines (LF) to DOS format.
sed "s/$//"    # method 1
sed -n p       # method 2
  • IN DOS ENVIRONMENT: convert DOS newlines (CR/LF) to Unix format. Can only be done with UnxUtils sed, version 4.0.7 or higher. The UnxUtils version can be identified by the custom "--text" switch which appears when you use the "--help" switch. Otherwise, changing DOS newlines to Unix newlines cannot be done with sed in a DOS environment. Use "tr" instead.
sed "s/\r//" infile >outfile   # UnxUtils sed v4.0.7 or higher
tr -d \r <infile >outfile      # GNU tr version 1.22 or higher
  • delete leading whitespace (spaces, tabs) from front of each line aligns all text flush left
sed 's/^[ \t]*//'      # see note on '\t' at end of file
  • delete trailing whitespace (spaces, tabs) from end of each line
sed 's/[ \t]*$//'      # see note on '\t' at end of file
  • delete BOTH leading and trailing whitespace from each line
sed 's/^[ \t]*//;s/[ \t]*$//'
  • insert 5 blank spaces at beginning of each line (make page offset)
sed 's/^/     /'
  • break up a stream of characters into 60 per line (i.e. 60-column width)[1]
sed -e 's/\(.\{60\}\)/\1\n/g'
  • align all text flush right on a 79-column width
sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # set at 78 plus 1 space
  • center all text in the middle of 79-column width. In method 1, spaces at the beginning of the line are significant, and trailing spaces are appended at the end of the line. In method 2, spaces at the beginning of the line are discarded in centering the line, and no trailing spaces appear at the end of lines.
sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # method 1
sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # method 2
  • substitute (find and replace) "foo" with "bar" on each line
sed 's/foo/bar/'             # replaces only 1st instance in a line
sed 's/foo/bar/4'            # replaces only 4th instance in a line
sed 's/foo/bar/g'            # replaces ALL instances in a line
sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # replace the next-to-last case
sed 's/\(.*\)foo/\1bar/'            # replace only the last case
  • substitute "foo" with "bar" ONLY for lines which contain "baz"
sed '/baz/s/foo/bar/g'
  • substitute "foo" with "bar" EXCEPT for lines which contain "baz"
sed '/baz/!s/foo/bar/g'
  • change ("scarlet" or "ruby" or "puce") to ("red")
sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'   # most seds

gsed 's/scarlet\|ruby\|puce/red/g'                # GNU sed only
  • reverse order of lines (emulates "tac") bug/feature in HHsed v1.5 causes blank lines to be deleted
sed '1!G;h;$!d'               # method 1
sed -n '1!G;h;$p'             # method 2
  • reverse each character on the line (emulates "rev")
sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
  • join pairs of lines side-by-side (like "paste")
sed '$!N;s/\n/ /'
  • delete all newlines (i.e. append next line loop)[1]
sed -e :a -e '$!N;s/\n//;ta'    # method 1
sed -e :a -e '$b;N;s/\n//;ba'   # method 2
  • if a line ends with a backslash, append the next line to it
sed -e :a -e '/\\$/N; s/\\\n//; ta'
  • if a line begins with an equal sign, append it to the previous line and replace the "=" with a single space
sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'
  • add commas to numeric strings, changing "1234567" to "1,234,567"
gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                     # GNU sed
sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # other seds
  • add commas to numbers with decimal points and minus signs (GNU sed)
gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'
  • add a blank line every 5 lines (after lines 5, 10, 15, 20, etc.)
gsed '0~5G'                  # GNU sed only
sed 'n;n;n;n;G;'             # other seds

Selective printing of certain lines

  • print first 10 lines of file (emulates behaviour of "head")
sed 10q
  • print first line of file (emulates "head -1")
sed q
  • print the last 10 lines of a file (emulates "tail")
sed -e :a -e '$q;N;11,$D;ba'
  • print the last 2 lines of a file (emulates "tail -2")
sed '$!N;$!D'
  • print the last line of a file (emulates "tail -1")
sed '$!d'                    # method 1
sed -n '$p'                  # method 2
  • print the next-to-the-last line of a file
sed -e '$!{h;d;}' -e x              # for 1-line files, print blank line
sed -e '1{$q;}' -e '$!{h;d;}' -e x  # for 1-line files, print the line
sed -e '1{$d;}' -e '$!{h;d;}' -e x  # for 1-line files, print nothing
  • print only lines which match regular expression (emulates "grep")
sed -n '/regexp/p'           # method 1
sed '/regexp/!d'             # method 2
  • print only lines which do NOT match regexp (emulates "grep -v")
sed -n '/regexp/!p'          # method 1, corresponds to above
sed '/regexp/d'              # method 2, simpler syntax
  • print the line immediately before a regexp, but not the line containing the regexp
sed -n '/regexp/{g;1!p;};h'
  • print the line immediately after a regexp, but not the line containing the regexp
sed -n '/regexp/{n;p;}'
  • print 1 line of context before and after regexp, with line number indicating where the regexp occurred (similar to "grep -A1 -B1")
sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h
  • grep for AAA and BBB and CCC (in any order)
sed '/AAA/!d; /BBB/!d; /CCC/!d'
  • grep for AAA and BBB and CCC (in that order)
sed '/AAA.*BBB.*CCC/!d'
  • grep for AAA or BBB or CCC (emulates "egrep")
sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    # most seds
gsed '/AAA\|BBB\|CCC/!d'                        # GNU sed only
  • print paragraph if it contains AAA (blank lines separate paragraphs) HHsed v1.5 must insert a 'G;' after 'x;' in the next 3 scripts below
sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'
  • print paragraph if it contains AAA and BBB and CCC (in any order)
sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'
  • print paragraph if it contains AAA or BBB or CCC
sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         # GNU sed only
  • print only lines of 65 characters or longer
sed -n '/^.\{65\}/p'
  • print only lines of less than 65 characters
sed -n '/^.\{65\}/!p'        # method 1, corresponds to above
sed '/^.\{65\}/d'            # method 2, simpler syntax
  • print section of file from regular expression to end of file
sed -n '/regexp/,$p'
  • print section of file based on line numbers (lines 8-12, inclusive)
sed -n '8,12p'               # method 1
sed '8,12!d'                 # method 2
  • print line number 52
sed -n '52p'                 # method 1
sed '52!d'                   # method 2
sed '52q;d'                  # method 3, efficient on large files
  • beginning at line 3, print every 7th line
gsed -n '3~7p'               # GNU sed only
sed -n '3,${p;n;n;n;n;n;n;}' # other seds
  • print section of file between two regular expressions (inclusive)
sed -n '/Iowa/,/Montana/p'             # case sensitive
  • print only the last line that matches REGEX pattern:
sed -ne '/REGEX/h;${x;p}'

Selective deletion of certain lines

  • print all of file EXCEPT section between 2 regular expressions
sed '/Iowa/,/Montana/d'
  • delete every paragraph containing "FOO"[1]
sed -e '/^$/b; :loop; $!{ N; /\n$/!b loop; }; /FOO/d'
  • delete duplicate, consecutive lines from a file (emulates "uniq"). First line in a set of duplicate lines is kept, rest are deleted.
sed '$!N; /^\(.*\)\n\1$/!P; D'
  • delete duplicate, nonconsecutive lines from a file. Beware not to overflow the buffer size of the hold space, or else use GNU sed.
sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'
  • delete all lines except duplicate lines (emulates "uniq -d").
sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'
  • delete the first 10 lines of a file
sed '1,10d'
  • delete the last line of a file
sed '$d'
  • delete the last 2 lines of a file
sed 'N;$!P;$!D;$d'
  • delete the last 10 lines of a file
sed -e :a -e '$d;N;2,10ba' -e 'P;D'   # method 1
sed -n -e :a -e '1,10!{P;N;D;};N;ba'  # method 2
  • delete every 8th line
gsed '0~8d'                           # GNU sed only
sed 'n;n;n;n;n;n;n;d;'                # other seds
  • delete lines matching pattern
sed '/pattern/d'
  • delete ALL blank lines from a file (same as "grep '.' ")
sed '/^$/d'                           # method 1
sed '/./!d'                           # method 2
  • delete all CONSECUTIVE blank lines from file except the first; also deletes all blank lines from top and end of file (emulates "cat -s")
sed '/./,/^$/!d'          # method 1, allows 0 blanks at top, 1 at EOF
sed '/^$/N;/\n$/D'        # method 2, allows 1 blank at top, 0 at EOF
  • delete all CONSECUTIVE blank lines from file except the first 2:
sed '/^$/N;/\n$/N;//D'
  • delete all leading blank lines at top of file
sed '/./,$!d'
  • delete all trailing blank lines at end of file
sed -e :a -e '/^\n*$/{$d;N;ba' -e '}'  # works on all seds
sed -e :a -e '/^\n*$/N;/\n$/ba'        # ditto, except for gsed 3.02.*
  • delete the last line of each paragraph
sed -n '/^$/{p;h;};/./{x;/./p;}'
  • delete (strip) all HTML tags (not the line, just the tag; e.g. <p></p>):[1]
sed -e 's#<[^>]*>##g'
#~OR~
sed -e 's/<[^>]*>//g'
#~OR~
sed 's/<[^>]\+>//g'


  • delete (strip) all text within brackets/parentheses, including the brackets/parentheses:
$ echo "foo [bar] baz" | sed -e 's/\[[^][]*\]//g' # => "foo  baz"
$ echo "foo (bar) baz" | sed -e 's/([^()]*)//g'   # => "foo  baz"

Date formats

  • Convert from "10/20/1998" to "1998-10-20"[1]
$ sed -n -e "s_\(..\)/\(..\)/\(....\)_\3-\1-\2_p"
$ #~OR~
$ echo 10/20/1998 |sed -E 's,([0-9]{2})/([0-9]{2})/([0-9]{4}),\3-\2-\1,g'

Note: You can also accomplish the above with: 

$ date --date='10/20/1998' '+%F'

Special applications

  • remove nroff overstrikes (char, backspace) from man pages. The 'echo' command may need an -e switch if you use Unix System V or bash shell.
sed "s/.`echo \\\b`//g"    # double quotes required for Unix environment
sed 's/.^H//g'             # in bash/tcsh, press Ctrl-V and then Ctrl-H
sed 's/.\x08//g'           # hex expression for sed 1.5, GNU sed, ssed
  • get Usenet/e-mail message header
sed '/^$/q'                # deletes everything after first blank line
  • get Usenet/e-mail message body
sed '1,/^$/d'              # deletes everything up to first blank line
  • get Subject header, but remove initial "Subject: " portion
sed '/^Subject: */!d; s///;q'
  • get return address header
sed '/^Reply-To:/q; /^From:/h; /./d;g;q'
  • parse out the address proper. Pulls out the e-mail address by itself from the 1-line return address header (see preceding script)
sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'
  • add a leading angle bracket and space to each line (quote a message)
sed 's/^/> /'
  • delete leading angle bracket & space from each line (unquote a message)
sed 's/^> //'
  • remove most HTML tags (accommodates multiple-line tags)
sed -e :a -e 's/<[^>]*>//g;/</N;//ba'
  • extract multi-part uuencoded binaries, removing extraneous header info, so that only the uuencoded portion remains. Files passed to sed must be passed in the proper order. Version 1 can be entered from the command line; version 2 can be made into an executable Unix shell script. (Modified from a script by Rahul Dhesi.)
sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode   # vers. 1
sed '/^end/,/^begin/d' "$@" | uudecode                    # vers. 2
  • sort paragraphs of file alphabetically. Paragraphs are separated by blank lines. GNU sed uses \v for vertical tab, or any unique char will do.
sed '/./{H;d;};x;s/\n/={NL}=/g' file | sort | sed '1s/={NL}=//;s/={NL}=/\n/g'
gsed '/./{H;d};x;y/\n/\v/' file | sort | sed '1s/\v//;y/\v/\n/'
  • zip up each .TXT file individually, deleting the source file and setting the name of each .ZIP file to the basename of the .TXT file (under DOS: the "dir /b" switch returns bare filenames in all caps).
echo @echo off >zipup.bat
dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat

Miscellaneous

  • Replace string1 with string2[1]
sed 's/string1/string2/g'
  • Modify anystring1 to anystring2[1]
sed 's/\(.*\)1/\12/g'
  • Remove comments and blank lines[1]
sed '/ *#/d; /^ *$/d'
  • Concatenate lines with trailing \[1]
sed ':a; /\\$/N; s/\\\n//; ta'
  • Remove trailing spaces from lines[1]
sed 's/[ \t]*$//'
  • Escape shell metacharacters active within double quotes[1]
sed 's/\([\\`\\"$\\\\]\)/\\\1/g'
  • Print 1000th line[1]
sed -n '1000p;1000q'
  • Print lines 10 to 20[1]
sed -n '10,20p;20q'
  • Extract title from HTML web page[1]
sed -n 's/.*<[tT][iI][tT][lL][eE]>\(.*\)<\/[tT][iI][tT][lL][eE]>.*/\1/p;T;q'
  • Sort IPV4 ip addresses[1]
sort -t. -k1,1n -k2,2n -k3,3n -k4,4n
  • Insert text at a given line (e.g., insert "foo" into a file at line 5):
sed -i '5i foo' file.txt
  • Case conversion[1]
echo 'Test' | tr '[:lower:]' '[:upper:]'
  • Filter non printable characters[1]
tr -dc '[:print:]' < /dev/urandom
  • Count lines[1]
grep 'processor' /proc/cpuinfo | wc -l
  • In line 2, looks for the string 'limits.*' where * is any string, and replaces with 'hello'[2]
sed '2 s/limits.*/hello/'
  • Substitutes 'try' for the first occurence of 'junk' in lines 2 through 4 only[2]
sed '2,4 s/junk/try/
  • Appends the string 'set c=818.' after line 8[2]
sed '8 a\set c=818.'
  • Appends the string 'set i1=(i+c)/c - 1' after line 8. Note the use of the \ is needed to print out 'special characters', like /, &, %, $, and of course, \ itself[2]
sed '8 a\set i1=(i+c)\/c - 1'
  • Inserts the string 'set c=818.' before line 8[2]
sed '8 i\set c=818.'
  • Piping streams through sed[2]
ls file* | sed 's/.*/cat & | sed -f a.sed > tmp; mv -f tmp &/' > doit
  • Append lines n,m in a loop[1]

Say you have a file, foo, that has the following 10 lines: 

A1
A2
A3
A4
A5
B1
B2
B3
B4
B5

and you want to convert it to look like the following: 

A1A2A3A4A5
B1B2B3B4B5

Then, issue this command: 

for i in $(seq 1 5 10);\
  do sed -n $(echo "$i,$(echo -e "$i+4"|bc -q)")'p' foo |\
     sed -e :a -e '$b;N;s/\n//;ba';\
done

Note: There are easier ways to accomplish this; I am just showing a cool way to do it with sed.

  • Convert from rows to numbered columns[1]

Say you have a file, foo, that has the following (single) line: 

FOO1   FOO2 BAR1 BAR2

where the spaces can be any length and/or tabs.

If you wish the output to look like the following: 

1     FOO1
2     FOO2
3     BAR1
4     BAR2

Then, issue this command: 

sed -e 's/[ \t]/\n/g' -e '/^$/d'|sed =|sed 'N;s/\n/\t/'

(.*): (.*)/

  • Convert named telephone numbers:
sed 's/[abc]/2/gi;s/[def]/3/gi;s/[ghi]/4/gi;s/[jkl]/5/gi;s/[mno]/6/gi;s/[pqrs]/7/gi;s/[tuv]/8/gi;s/[wxyz]/9/gi' <<<"1-800-SHOWNUM"
  • Increment the first digit in a number in a string with single quotes:
# '101': 'foo' -> '201': 'foo'
echo "'101': 'foo'"|sed -r -e "s/'//g" -e 's/([0-9])(.*): (.*)/echo $((\1+1))\2: \3/e' -e "s/(.*): (.*)/\\'\1\\': \\'\2\\'/"
  • Pipe redirection:
$ echo "foo" | sed -e 's/o/X/g' <&0
fXX
  • Directory nested tree:
$ find . -type d | sed 's:[^-][^/]*/:--:g; s:^-: |:'
  • Rename similar files such that the "date" part of the filename will change to be one day behind the original without overwriting the contents of the files:
# E.g., Rename:      FROM -> TO
# results-2014-10-09.json -> results-2014-10-08.json
# results-2014-10-10.json -> results-2014-10-09.json
# results-2014-10-11.json -> results-2014-10-10.json
for f in *.json; do\
  mv "$f" "$(echo $f|sed -e 's|\(results-\)\(.*\).json|echo $(date -d "\2-1day" +"%F")XXX\1|e' -e 's/\(.*\)XXX\(.*\)/\2\1.json/')"
done

One could accomplish a similar way of renaming files using pure Bash: 

# Rename:
# FROM: "Introduction___Networking_tutorial_(1_of_13)-qHzZUmP1vvON.mp4"
#   TO: "nettut-01_of_13_-_Introduction-qHzZUmP1vvON.mp4"
for f in *.mp4; do \
  [[ $f =~ ^(.*)___Networking_tutorial_\(([0-9]+)_of_13\)-(.*)$ ]]
  mv "$f" "nettut-$(printf "%02d" ${BASH_REMATCH[2]})_of_13_-_${BASH_REMATCH[1]}-${BASH_REMATCH[3]}"
done

There are obviously much easier ways to do the above. This is just an example to show the power of Bash.

  • Parse output of ping for packet loss value:
$ ping -c 5 -W 0.2 -q www.google.com | sed -rn "/packet loss/ s|.*([0-9]+)%.*|\1|p"
  • Increment number in a given line matching the regex:
$ sed -i -r 's/^(security.provider.)([0-9]+)=(.*)/echo "\1\$((\2+1))=\3"/ge' java.security
  • Convert date formats:
$ cat transactions.csv 
"Date","Activity Type","Amount"
"07/22/19","bob","$23.51"
"07/18/19","alice","$67.92"
"06/21/19","bob","$12.42"

$ sed -n '/alice/p' transactions.csv |\
  sed -e 's/"\(.*\)",".*","\$\(.*\)"/echo $(date -d "\1" "+%Y-%m-%d") \2/e'
2019-07-18 67.92
  • Verify that a TLS certificate stored in a kubeconfig file has not expired:
$ cat ~/.kube/config
apiVersion: v1
kind: Config
clusters:
- name: "local"
  cluster:
    server: "https://rancher.example.com/k8s/clusters/local"
    certificate-authority-data: "LS0tLS1CRUdJTiBDRVJUSUZJQ0FURS0tLS0tCk1JSUdIRENDQ\
      kFTZ0F3SUJBZ0lKQU1vbTB2ZG5iTU9mTUEwR0NTcUdTSWIzRFFFQkN3VUFNSUdhTVFzd0NRWUQKV\
      lFRR0V3SlZVekVUTUJFR0ExVUVDQXdLVjJGemFHbHVaM1J2YmpFUU1BNEdBMVVFQnd3SFUyVmhkS\
      k3MVd0V3Brc3lpK1NJNWxpMGtLZCs4UDdKR0JkcGdZSkhWOWZib3E0WjBRWnNSeFRVClVnYeasdf"
...
users:
- name: "user-nff34"
...

$ sed -n '/certificate-authority-data/,/"/p' ~/.kube/config |\
  sed -e 's/certificate-authority-data://' -e :a -e '/\\$/N; s/\\\n//; s/ //g; s/"//g; ta' |\
  base64 -d | openssl x509 -enddate -noout -in -
notAfter=Aug  4 23:38:12 2038 GMT

Comments

Typical use

Sed takes one or more editing commands and applies all of them, in sequence, to each line of input. After all the commands have been applied to the first input line, that line is output and a second input line is taken for processing, and the cycle repeats. The preceding examples assume that input comes from the standard input device (i.e, the console, normally this will be piped input). One or more filenames can be appended to the command line if the input does not come from stdin. Output is sent to stdout (the screen). Thus: 

cat filename | sed '10q'        # uses piped input
sed '10q' filename              # same effect, avoids a useless "cat"
sed '10q' filename > newfile    # redirects output to disk

For additional syntax instructions, including the way to apply editing commands from a disk file instead of the command line, consult "sed & awk, 2nd Edition," by Dale Dougherty and Arnold Robbins (O'Reilly, 1997; http://www.ora.com), "UNIX Text Processing," by Dale Dougherty and Tim O'Reilly (Hayden Books, 1987) or the tutorials by Mike Arst distributed in U-SEDIT2.ZIP (many sites). To fully exploit the power of sed, one must understand "regular expressions." For this, see "Mastering Regular Expressions" by Jeffrey Friedl (O'Reilly, 1997). The manual ("man") pages on Unix systems may be helpful (try "man sed", "man regexp", or the subsection on regular expressions in "man ed"), but man pages are notoriously difficult. They are not written to teach sed use or regexps to first-time users, but as a reference text for those already acquainted with these tools.

Quoting syntax

The preceding examples use single quotes ('...') instead of double quotes ("...") to enclose editing commands, since sed is typically used on a Unix platform. Single quotes prevent the Unix shell from intrepreting the dollar sign ($) and backquotes (`...`), which are expanded by the shell if they are enclosed in double quotes. Users of the "csh" shell and derivatives will also need to quote the exclamation mark (!) with the backslash (i.e., \!) to properly run the examples listed above, even within single quotes. Versions of sed written for DOS invariably require double quotes ("...") instead of single quotes to enclose editing commands.

Use of '\t' in sed scripts

For clarity in documentation, we have used the expression '\t' to indicate a tab character (0x09) in the scripts. However, most versions of sed do not recognize the '\t' abbreviation, so when typing these scripts from the command line, you should press the TAB key instead. '\t' is supported as a regular expression metacharacter in awk, perl, and HHsed, sedmod, and GNU sed v3.02.80.

Versions of sed

Versions of sed do differ, and some slight syntax variation is to be expected. In particular, most do not support the use of labels (:name) or branch instructions (b,t) within editing commands, except at the end of those commands. We have used the syntax which will be portable to most users of sed, even though the popular GNU versions of sed allow a more succinct syntax. When the reader sees a fairly long command such as this: 

  sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

it is heartening to know that GNU sed will let you reduce it to: 

  sed '/AAA/b;/BBB/b;/CCC/b;d'      # or even
  sed '/AAA\|BBB\|CCC/b;d'

In addition, remember that while many versions of sed accept a command like "/one/ s/RE1/RE2/", some do NOT allow "/one/! s/RE1/RE2/", which contains space before the 's'. Omit the space when typing the command.

Optimizing for speed

If execution speed needs to be increased (due to large input files or slow processors or hard disks), substitution will be executed more quickly if the "find" expression is specified before giving the "s/.../.../" instruction. Thus: 

sed 's/foo/bar/g' filename         # standard replace command
sed '/foo/ s/foo/bar/g' filename   # executes more quickly
sed '/foo/ s//bar/g' filename      # shorthand sed syntax

On line selection or deletion in which you only need to output lines from the first part of the file, a "quit" command (q) in the script will drastically reduce processing time for large files. Thus: 

sed -n '45,50p' filename           # print line nos. 45-50 of a file
sed -n '51q;45,50p' filename       # same, but executes much faster

POSIX character classes

Note: See `man 1 tr`.

POSIX Description ASCII Unicode Shorthand
[:alnum:] Alphanumeric characters [a-zA-Z0-9] [\p{L&}\p{Nd}]
[:alpha:] Alphabetic characters [a-zA-Z] \p{L&}
[:ascii:] ASCII characters [\x00-\x7F] \p{InBasicLatin}
[:blank:] Space and tab [ \t] [\p{Zs}\t] \h
[:cntrl:] Control characters [\x00-\x1F\x7F] \p{Cc}
[:digit:] Digits [0-9] \p{Nd} \d
[:graph:] Visible characters (i.e. anything except spaces, control characters, etc.) [\x21-\x7E] [^\p{Z}\p{C}]
[:lower:] Lowercase letters [a-z] \p{Ll}
[:print:] Visible characters and spaces (i.e. anything except control characters, etc.) [\x20-\x7E] \P{C}
[:punct:] Punctuation and symbols [!"#$%&'()*+,\-./:;<=>?@[\\\]^_`{|}~] [\p{P}\p{S}]
[:space:] All whitespace characters, including line breaks [ \t\r\n\v\f] [\p{Z}\t\r\n\v\f] \s
[:upper:] Uppercase letters [A-Z] \p{Lu}
[:word:] Word characters (letters, numbers, and underscores) [A-Za-z0-9_] [\p{L}\p{N}\p{Pc}] \w
[:xdigit:] Hexadecimal digits [A-Fa-f0-9] [A-Fa-f0-9]

Note that not all of the above character classes are understood by earlier versions of `sed` and/or even by the latest versions. 

$ echo "10,20,30"|sed -r 's/[[:digit:]]+,([[:digit:]]+),[[:digit:]]+/\1/' # => 20

$ echo "10,foo,(2007),bar" | sed -r 's/^[[:digit:]]+,.*,\(([[:digit:]]+)\),.*/\1/' # => 2007

Credits

If you have any additional scripts to contribute or if you find errors in this document, please send e-mail to the compiler. Indicate the version of sed you used, the operating system it was compiled for, and the nature of the problem. To qualify as a one-liner, the command line must be 65 characters or less. Various scripts in this file have been written or contributed by:

  • Al Aab — founder of "seders" list
  • Edgar Allen — various
  • Yiorgos Adamopoulos — various
  • Dale Dougherty — author of "sed & awk"
  • Carlos Duarte — author of "do it with sed"
  • Eric Pement — author of this document
  • Ken Pizzini — author of GNU sed v3.02
  • S.G. Ravenhall — great de-html script
  • Greg Ubben — many contributions & much help
  1. ↑ 1.00 1.01 1.02 1.03 1.04 1.05 1.06 1.07 1.08 1.09 1.10 1.11 1.12 1.13 1.14 1.15 1.16 1.17 1.18 1.19 Christoph Champ's additions
  2. ↑ 2.0 2.1 2.2 2.3 2.4 2.5 Patrick Hartigan's additions

Further reading

  • Sed & Awk, 2nd ed.; by Dougherty, Dale and Robbins, Arnold; from Oreilly & Associates, ISBN 1-56592-225-5
  • Sed & Awk Pocket Reference; by Robbins, Arnold; from Oreilly & Associates, ISBN 1-56592-729-X
  • Unix Awk and Sed Programmer's Interactive Workbook; by Patsis, Peter; from Prentice Hall Computer Books, ISBN 0130826758
  • Mastering Regular Expressions, 2nd ed.; by Jeffrey E. F. Friedl; from O'Reilly & Associates, ISBN 0-596-00289-0

See also

External links

Retrieved from "http://wiki.christophchamp.com/index.php?title=Sed/scripts&oldid=7609"